Siempre he sido especialmente sensible con el tema de la ceguera. ¿Cómo sería mi vida si me quedase ciego súbitamente? ¿Podría seguir viviendo de manera independiente?
Este proyecto surge de esa inquietud. La idea es crear un dispositivo que pueda suplir parcialmente al sentido de la vista, que esté al alcance de todo el mundo (que sea barato), que sea lo más sencillo posible (
la perfection est atteinte, non pas lorsqu'il n'y a plus rien à ajouter, mais lorsqu'il n'y a plus rien à retirer) y que sea realmente práctico. Hay
varios proyectos similares de gran interés, pero la verdad es que nunca he visto ningún ciego con dispositivos electrónicos de ayuda (quizá porque nunca me he fijado lo suficiente).
Considero que el proyecto tiene dos partes fundamentales:
- Percepción del entorno. Lo ideal es que la información obtenida sea lo más ajustada posible a la realidad.
- Transmisión de la información al usuario. Ésta me parece la parte más complicada del proyecto. ¿Cómo convertimos las "imágenes" percibidas anteriormente a otro formato que pueda ser percibido por personas invidentes? Y antes de responder a esa pregunta, ¿qué otro formato elegimos? ¿Sonidos? ¿Olores? ¿Sabores? ¿Vibraciones? ¿Temperaturas? ¿Movimientos? ¿Presiones?
Un primer intento muy sencillo puede consistir en utilizar un sensor de distancia para detectar obstáculos y transmitir la información al usuario por medio de sonidos o vibraciones.
Usando Arduino, un sensor de ultrasonidos PING))) y un zumbador, he creado el primer prototipo. ¿A que es bonito? ;)
El código (más abajo) está basado en el ejemplo "Ping" contenido en el software de desarrollo de Arduino. Básicamente, se envía un pulso de 5 microsegundos al sensor y éste devuelve un pulso, que se mantiene HIGH el tiempo que pasa desde que se emite el sonido hasta que se escucha el eco. El programa mide ese tiempo y, sabiendo que la velocidad del sonido en el aire es de unos 340m/s y que el sonido realiza dos recorridos (ida y vuelta hasta el objeto que produce el eco), calcula la distancia al objeto y la "imprime" por el puerto serie para poder verla en el Serial Monitor.
Hasta aquí la percepción de objetos del entorno. Ahora hay que transmitir esa información al usuario, en este caso usando sonidos. He dividido el entorno del usuario en tres zonas o segmentos:
- La zona más próxima, hasta 1 metro de distancia (en rojo en la figura).
- Una zona intermedia, de 1 a 2 metros de distancia (en amarillo en la figura).
- La zona lejana, de objetos a más de dos metros de distancia (en verde en la figura).
Por tanto, la información que aportará el dispositivo al usuario será la zona en que se encuentran los objetos que le rodean. ¿Están muy cerca, o no tanto?
Para ello, he asignado a cada zona un sonido característico, de forma que cada vez que un objeto entre en una zona en la que no estaba, se escuche el sonido característico de dicha zona. La variable segmento almacena la zona en la que se encuentra en cada instante el objeto detectado por el sensor.
Ejemplo - Voy andando por la calle y no tengo nada delante. Estoy en la zona verde. Sigo andando y me aproximo a una farola. En el momento en que la farola esté a menos de dos metros de mí, se escuchará el sonido característico de la zona amarilla. Así, sé que hay algún objeto a menos de dos metros de mí, y puedo andar con más cuidado. Cuando llegue a estar a menos de un metro de la farola, se escuchará el sonido característico de la zona roja. Esto me indicará que estoy a menos de un metro del objeto en sí, y probablemente estiraré los brazos para saber qué tengo en frente.
Si probáis a hacerlo tal cual, es muy probable que estéis todo el tiempo escuchando sonidos, cambiando de zona. Probablemente sea debido al ruido generado por el sensor. Para evitar estas "medidas falsas", he creado unas variables de constancia. La idea es que para considerar que realmente hemos cambiado de zona, el sensor debe medir 10 veces seguidas (o 5, o 15,... habrá que configurarlo en función del entorno) una distancia comprendida en esa zona.
Ejemplo - El sensor está midiendo una distancia de 257 cm a un objeto. Estamos en la zona verde. De repente, sin que nada se mueva, el sensor mide una distancia de 134 cm, volviendo a medir 257 cm en la siguiente lectura. Sin variables de constancia, escucharíamos el sonido de la zona amarilla y en seguida el de la zona verde de nuevo. Esto se repite con bastante frecuencia, lo que hace el dispositivo muy confuso (inutilizable).
Esta primera versión funciona aceptablemente. Trataré de montar el Crémilo de forma que pueda llevarse encima cómodamente y haré algunas pruebas.
---
Posibles mejoras:
- Creo que el dispositivo sería más práctico sustituyendo el sistema de sonidos por un sistema de vibraciones. Para los invidentes, escuchar los sonidos de su entorno es muy importante, y todo lo que suponga interferir en eso parece poco práctico.
- Probablemente convenga introducir un segundo sensor para aumentar la fiabilidad del dispositivo, aunque esto se valorará después de las pruebas reales.
---
Código:
/* Proyecto Crémilo (basado en el ejemplo Ping))) de Arduino
Ping))) Sensor
This sketch reads a PING))) ultrasonic rangefinder and returns the
distance to the closest object in range. To do this, it sends a pulse
to the sensor to initiate a reading, then listens for a pulse
to return. The length of the returning pulse is proportional to
the distance of the object from the sensor.
The circuit:
* +V connection of the PING))) attached to +5V
* GND connection of the PING))) attached to ground
* SIG connection of the PING))) attached to digital pin 7
http://www.arduino.cc/en/Tutorial/Ping
created 3 Nov 2008
by David A. Mellis
modified 30 Jun 2009
by Tom Igoe
modified 14 Aug 2011
by Jose Alberto
This example code is in the public domain.
*/
// this constant won't change. It's the pin number
// of the sensor's output:
const int pingPin = 7;
const int pinZumbador = 2;
int segmento; // 0 (0 a 1m), 1 (1 a 2m), 2 (2 a 3m)
const int constancia = 10;
int constancia0; // Al menos "constancia" medidas seguidas iguales
int constancia1; // Al menos "constancia" medidas seguidas iguales
int constancia2; // Al menos "constancia" medidas seguidas iguales
void setup() {
// initialize serial communication:
Serial.begin(9600);
}
void loop()
{
// establish variables for duration of the ping,
// and the distance result in inches and centimeters:
long duration, inches, cm;
// The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
// Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
pinMode(pingPin, OUTPUT);
digitalWrite(pingPin, LOW);
delayMicroseconds(2);
digitalWrite(pingPin, HIGH);
delayMicroseconds(5);
digitalWrite(pingPin, LOW);
// The same pin is used to read the signal from the PING))): a HIGH
// pulse whose duration is the time (in microseconds) from the sending
// of the ping to the reception of its echo off of an object.
pinMode(pingPin, INPUT);
duration = pulseIn(pingPin, HIGH);
// convert the time into a distance
inches = microsecondsToInches(duration);
cm = microsecondsToCentimeters(duration);
Serial.print(inches);
Serial.print("in, ");
Serial.print(cm);
Serial.print("cm, ");
Serial.print(segmento);
Serial.println();
// Zumbador
pinMode(pinZumbador, OUTPUT);
if((cm < 100) && (segmento != 0))
{
constancia0++;
constancia1 = 0;
constancia2 = 0;
if(constancia0 >= constancia)
{
segmento = 0;
tone(pinZumbador, 262, 500);
}
}
if((cm < 200) && (cm >100) && (segmento != 1))
{
constancia1++;
constancia0 = 0;
constancia2 = 0;
if(constancia1 >= constancia)
{
segmento = 1;
tone(pinZumbador, 524, 500);
}
}
if((cm > 200) && (segmento != 2))
{
constancia2++;
constancia0 = 0;
constancia1 = 0;
if(constancia2 >= constancia)
{
segmento = 2;
tone(pinZumbador, 1048, 200);
}
}
delay(100);
}
long microsecondsToInches(long microseconds)
{
// According to Parallax's datasheet for the PING))), there are
// 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
// second). This gives the distance travelled by the ping, outbound
// and return, so we divide by 2 to get the distance of the obstacle.
// See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
return microseconds / 74 / 2;
}
long microsecondsToCentimeters(long microseconds)
{
// The speed of sound is 340 m/s or 29 microseconds per centimeter.
// The ping travels out and back, so to find the distance of the
// object we take half of the distance travelled.
return microseconds / 29 / 2;
}
